Vytvoření dokumentu s obory názvů v jazyce Visual Basic (LINQ to XML)

Tento článek ukazuje, jak vytvořit dokument s obory názvů v jazyce Visual Basic.

Při použití literálů XML v jazyce Visual Basic mohou uživatelé definovat jeden globální výchozí obor názvů XML. Tento obor názvů je výchozím oborem názvů pro literály XML i vlastnosti XML. Výchozí obor názvů XML lze definovat na úrovni projektu nebo na úrovni souboru. Pokud je definována na úrovni souboru, přepíše výchozí obor názvů na úrovni projektu.

Můžete také definovat další obory názvů a zadat předpony oboru názvů pro tyto obory názvů. Klíčové slovo slouží Imports k definování obou typů oboru názvů.

Další informace naleznete v tématu Literály XML v jazyce Visual Basic.

Všimněte si, že výchozí obor názvů XML se vztahuje pouze na elementy, nikoli na atributy. Ve výchozím oboru názvů jsou atributy ve výchozím nastavení. K vložení atributu do oboru názvů však můžete použít předponu oboru názvů.

Příklad: Vytvoření dokumentu s oborem názvů

Tento příklad vytvoří dokument, který obsahuje obor názvů.

Imports <xmlns:aw="http://www.adventure-works.com">
Module Module1
    Sub Main()
        Dim root As XElement = _
            <aw:Root>
                <aw:Child aw:Att="attvalue"/>
            </aw:Root>
        Console.WriteLine(root)
    End Sub
End Module

Tento příklad vytvoří následující výstup:

<aw:Root xmlns:aw="http://www.adventure-works.com">
  <aw:Child aw:Att="attvalue" />
</aw:Root>

Příklad: Vytvoření dokumentu, který má dva obory názvů, jeden s předponou

Tento příklad vytvoří dokument, který obsahuje dva obory názvů. Jeden je výchozí obor názvů, druhý má předponu.

Imports <xmlns="http://www.adventure-works.com">
Imports <xmlns:fc="www.fourthcoffee.com">

Module Module1

    Sub Main()
        Dim root As XElement = _
            <Root>
                <Child Att="attvalue"/>
                <fc:Child2>child2 content</fc:Child2>
            </Root>
        Console.WriteLine(root)
    End Sub

End Module

Tento příklad vytvoří následující výstup:

<Root xmlns:fc="www.fourthcoffee.com" xmlns="http://www.adventure-works.com">
  <Child Att="attvalue" />
  <fc:Child2>child2 content</fc:Child2>
</Root>

Příklad: Vytvoření dokumentu, který má dva obory názvů, oba s předponami

Následující příklad vytvoří dokument, který obsahuje dva obory názvů, oba mají předpony oboru názvů.

Při serializaci stromu XML linQ to XML generuje deklarace oboru názvů podle potřeby, aby každý prvek byl v jeho určeném oboru názvů.

Imports <xmlns:aw="http://www.adventure-works.com">
Imports <xmlns:fc="www.fourthcoffee.com">

Module Module1

    Sub Main()
        Dim root As XElement = _
            <aw:Root>
                <fc:Child>
                    <aw:DifferentChild>other content</aw:DifferentChild>
                </fc:Child>
                <aw:Child2>c2 content</aw:Child2>
                <fc:Child3>c3 content</fc:Child3>
            </aw:Root>
        Console.WriteLine(root)
    End Sub

End Module

Tento příklad vytvoří následující výstup:

<aw:Root xmlns:fc="www.fourthcoffee.com" xmlns:aw="http://www.adventure-works.com">
  <fc:Child>
    <aw:DifferentChild>other content</aw:DifferentChild>
  </fc:Child>
  <aw:Child2>c2 content</aw:Child2>
  <fc:Child3>c3 content</fc:Child3>
</aw:Root>

Viz také

  • Last updated on