INFO. ANMÆRKNINGER

Gælder for: beregnet kolonne beregnet tabel måling visuel beregning DAX forespørgsel

Returnerer en tabel med oplysninger om hver anmærkning i den semantiske model. Disse oplysninger hjælper dig med at forstå modellen.

Syntaks

INFO.ANNOTATIONS ( [<Restriction name>, <Restriction value>], ... )

Parametre

Parametre er valgfrie for denne DAX funktion. Når der bruges parametre, skal begge angives. Mere end ét par parametre er tilladt. Begrænsningsnavnet og -værdien er tekst og indtastet i dobbelte anførselstegn.

Udtryk Definition
Begrænsningsnavn Navnet på den begrænsning, der bruges til at filtrere resultaterne.
Begrænsningsværdi Værdi, der bruges til at filtrere resultaterne af begrænsningen.

Restriktioner

Normalt kan alle kolonner i resultaterne af DAX-funktionen bruges som en begrænsning. Yderligere begrænsninger kan også være tilladt.

Returværdi

En tabel med følgende kolonner:

Kolonne Beskrivelse
[ID] En reference til objektet. Id'er genereres normalt automatisk og bør ikke ændres, når modellen er oprettet. Datatypen er ikke signeret lang (4 byte).
[ObjectID] En reference til det objekt, der ejer denne anmærkning.
[ObjectType] En reference til den objekttype, der ejer denne anmærkning.
[Navn] Navnet på objektet, der bruges i kode, script og forespørgsler.
[Værdi] Værdien af anmærkningen.
[ModifiedTime] Det tidspunkt, hvor objektet sidst blev ændret.

Bemærkninger

Kan kun køres af brugere med skrivetilladelse til den semantiske model og ikke, når de har direkte forbindelse til den semantiske model i Power BI Desktop. Denne funktion kan bruges i DAX forespørgslerog kan ikke bruges i beregninger.

Eksempel 1 – DAX forespørgsel

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	INFO.ANNOTATIONS()

Denne DAX forespørgsel returnerer en tabel med alle kolonnerne i denne DAX funktion.

Eksempel 2 – DAX forespørgsel med joinforbindelser

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	VAR _ObjectTypeEnum =
	DATATABLE(
	"ObjectType",INTEGER,
	"Object",STRING,
	{
	{0,"Null"},
	{1,"Model"},
	{2,"DataSource"},
	{3,"Table"},
	{4,"Column"},
	{5,"AttributeHierarchy"},
	{6,"Partition"},
	{7,"Relationship"},
	{8,"Measure"},
	{9,"Hierarchy"},
	{10,"Level"},
	{11,"Annotation"},
	{12,"KPI"},
	{13,"Culture"},
	{14,"ObjectTranslation"},
	{15,"LinguisticMetadata"},
	{29,"Perspective"},
	{30,"PerspectiveTable"},
	{31,"PerspectiveColumn"},
	{32,"PerspectiveHierarchy"},
	{33,"PerspectiveMeasure"},
	{34,"Role"},
	{35,"RoleMembership"},
	{36,"TablePermission"},
	{37,"Variation"},
	{38,"Set"},
	{39,"PerspectiveSet"},
	{40,"ExtendedProperty"},
	{41,"Expression"},
	{42,"ColumnPermission"},
	{43,"DetailRowsDefinition"},
	{44,"RelatedColumnDetails"},
	{45,"GroupByColumn"},
	{46,"CalculationGroup"},
	{47,"CalculationItem"},
	{48,"AlternateOf"},
	{49,"RefreshPolicy"},
	{50,"FormatStringDefinition"}
	}
	)

	VAR _INFO =
	INFO.ANNOTATIONS()

	VAR _CombinedTable =
	NATURALLEFTOUTERJOIN(
		_INFO,
		_ObjectTypeEnum
	)

	VAR _ModelObjects =
	UNION(
		SELECTCOLUMNS(
			INFO.MEASURES(),
			"ObjectID", [ID],
			"Object Name", [Name]
		),
		SELECTCOLUMNS(
			INFO.TABLES(),
			"ObjectID", [ID],
			"Object Name", [Name]
		),
		SELECTCOLUMNS(
			INFO.COLUMNS(),
			"ObjectID", [ID],
			"Object Name", [ExplicitName]
		),
		SELECTCOLUMNS(
			INFO.EXPRESSIONS(),
			"ObjectID", [ID],
			"Object Name", [Name]
		),
		SELECTCOLUMNS(
			INFO.MODEL(),
			"ObjectID", [ID],
			"Object Name", [Name]
		)
	)

	VAR _CombinedTable2 =
	NATURALLEFTOUTERJOIN(
		_CombinedTable,
		_ModelObjects
	)

	RETURN
		SELECTCOLUMNS(
			_CombinedTable2,
			"Object type", [Object],
			"Object", [Object Name],
			"Annotation name", [Name],
			"Annotation value", [Value]
		)
	ORDER BY [Annotation name]

Denne DAX forespørgsel returnerer en tabel med kun de angivne kolonner og forbinder den med andre funktioner i INFO-DAX og optællingstabellen.

Optællinger

Kolonner, der returneres i denne INFO-funktion, giver id'et for en optælling eller opslagstabel. Her er værdierne for hver optælling i denne DAX funktion.

ObjectType

Tal Værdi
0 Nul
1 Model
2 Datakilde
3 Bord
4 Kolonne
5 AttributeHierarchy
6 Partition
7 Forhold
8 Måle
9 Hierarki
10 Niveau
11 Annotation
12 KPI
13 Kultur
14 ObjectTranslation
15 LinguisticMetadata
29 Perspektiv
30 Perspektivtabel
31 Perspektivkolonne
32 PerspectiveHierarchy
33 Perspektivmåling
34 Rolle
35 Rollemedlemskab
36 Tabelpermission
37 Variation
38 Sæt
39 Perspektivsæt
40 ExtendedProperty
41 Udtryk
42 Kolonnepermission
43 DetailRowsDefinition
44 RelatedColumnDetails
45 GroupByColumn
46 CalculationGroup
47 CalculationItem
48 AlternateOf
49 RefreshPolicy
50 FormatStringDefinition

Denne tabel er baseret på den officielle dokumentation.

Hvis du vil joinforbinde med INFO-funktioner, skal du bruge denne DAX forespørgsel.

EVALUATE
	DATATABLE(
	"ObjectType",INTEGER,
	"Object",STRING,
	{
	{0,"Null"},
	{1,"Model"},
	{2,"DataSource"},
	{3,"Table"},
	{4,"Column"},
	{5,"AttributeHierarchy"},
	{6,"Partition"},
	{7,"Relationship"},
	{8,"Measure"},
	{9,"Hierarchy"},
	{10,"Level"},
	{11,"Annotation"},
	{12,"KPI"},
	{13,"Culture"},
	{14,"ObjectTranslation"},
	{15,"LinguisticMetadata"},
	{29,"Perspective"},
	{30,"PerspectiveTable"},
	{31,"PerspectiveColumn"},
	{32,"PerspectiveHierarchy"},
	{33,"PerspectiveMeasure"},
	{34,"Role"},
	{35,"RoleMembership"},
	{36,"TablePermission"},
	{37,"Variation"},
	{38,"Set"},
	{39,"PerspectiveSet"},
	{40,"ExtendedProperty"},
	{41,"Expression"},
	{42,"ColumnPermission"},
	{43,"DetailRowsDefinition"},
	{44,"RelatedColumnDetails"},
	{45,"GroupByColumn"},
	{46,"CalculationGroup"},
	{47,"CalculationItem"},
	{48,"AlternateOf"},
	{49,"RefreshPolicy"},
	{50,"FormatStringDefinition"}
	}
	)

Se også

  • Last updated on