INFO. ÆNDREDE EGENSKABER

Gælder for: beregnet kolonne beregnet tabel måling visuel beregning DAX forespørgsel

Returnerer en tabel med oplysninger om hver ændret egenskab i den semantiske model. Denne funktion indeholder metadata om egenskaber, der er blevet ændret i modellen.

Syntaks

INFO.CHANGEDPROPERTIES ( [<Restriction name>, <Restriction value>], ... )

Parametre

Parametre er valgfrie for denne DAX funktion. Når der bruges parametre, skal begge angives. Mere end ét par parametre er tilladt. Begrænsningsnavnet og -værdien er tekst og indtastet i dobbelte anførselstegn.

Periode Definition
Begrænsningsnavn Navnet på den begrænsning, der bruges til at filtrere resultaterne.
Begrænsningsværdi Værdi, der bruges til at filtrere resultaterne af begrænsningen.

Restriktioner

Normalt kan alle kolonner i resultaterne af DAX-funktionen bruges som en begrænsning. Yderligere begrænsninger kan også være tilladt.

Returværdi

En tabel med følgende kolonner:

Kolonnenavn Datatype Betegnelse
[ID] Integer Det entydige id for den ændrede egenskab
[ObjectID] Integer Id'et for det objekt, der har den ændrede egenskab
[ObjectType] Integer Den objekttype, der har den ændrede egenskab
[Egenskab] String Navnet på den egenskab, der blev ændret

Bemærkninger

  • Bruges typisk i DAX forespørgsler til at undersøge og dokumentere modelmetadata.
  • Tilladelser, der kræves, afhænger af værten. Det kan kræve modeladministratortilladelser at forespørge om komplette metadata.

Eksempel

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	INFO.CHANGEDPROPERTIES()

Eksempel 2 – DAX forespørgsel med joinforbindelser

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	VAR _ChangedProperties =
		INFO.CHANGEDPROPERTIES()

	VAR _Tables = 
		SELECTCOLUMNS(
			INFO.TABLES(),
			"ObjectID", [ID],
			"Object Name", [Name]
		)

	VAR _Columns = 
		SELECTCOLUMNS(
			INFO.COLUMNS(),
			"ObjectID", [ID],
			"Object Name", [ExplicitName]
		)

	VAR _AllObjects = 
		UNION(_Tables, _Columns)

	VAR _CombinedTable =
		NATURALLEFTOUTERJOIN(
			_ChangedProperties,
			_AllObjects
		)

	RETURN
		SELECTCOLUMNS(
			_CombinedTable,
			"Object Name", [Object Name],
			"Object Type", [ObjectType],
			"Changed Property", [Property]
		)
	ORDER BY [Object Name], [Changed Property]

Se også

  • Last updated on