INFO. AFHÆNGIGHEDER

Gælder for: beregnet kolonne beregnet tabel måling visuel beregning DAX forespørgsel

Returnerer en tabel med oplysninger om hver afhængighed i den semantiske model. Denne funktion indeholder metadata om objektafhængigheder og relationer mellem modelobjekter.

Syntaks

INFO.DEPENDENCIES ( [<Restriction name>, <Restriction value>], ... )

Parametre

Parametre er valgfrie for denne DAX funktion. Når der bruges parametre, skal begge angives. Mere end ét par parametre er tilladt. Begrænsningsnavnet og -værdien er tekst og indtastet i dobbelte anførselstegn.

Periode Definition
Begrænsningsnavn Navnet på den begrænsning, der bruges til at filtrere resultaterne.
Begrænsningsværdi Værdi, der bruges til at filtrere resultaterne af begrænsningen.

Restriktioner

Normalt kan alle kolonner i resultaterne af DAX-funktionen bruges som en begrænsning. Yderligere begrænsninger kan også være tilladt.

Returværdi

En tabel med følgende kolonner:

Kolonnenavn Datatype Betegnelse
[DATABASE_NAME] String Navnet på den database, der indeholder objektet
[OBJECT_TYPE] String Objektets type (f.eks. ATTRIBUTE_HIERARCHY, HIERARCHY, MEASURE)
[TABLE] String Navnet på den tabel, der indeholder objektet
[OBJEKT] String Navnet på objektet
[UDTRYK] String Udtryk, der er knyttet til objektet
[REFERENCED_OBJECT_TYPE] String Typen af det objekt, der refereres til
[REFERENCED_TABLE] String Navnet på den tabel, der indeholder det objekt, der refereres til
[REFERENCED_OBJECT] String Navnet på det objekt, der refereres til
[REFERENCED_EXPRESSION] String Udtryk for det objekt, der refereres til
[FORESPØRGSEL] String Forespørgselskontekst for afhængigheden

Bemærkninger

  • Bruges typisk i DAX forespørgsler til at undersøge og dokumentere modelmetadata.
  • Tilladelser, der kræves, afhænger af værten. Det kan kræve modeladministratortilladelser at forespørge om komplette metadata.

Eksempel

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	INFO.DEPENDENCIES()

Eksempel 2 – DAX forespørgsel med joinforbindelser

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	VAR _Dependencies =
		INFO.DEPENDENCIES()

	VAR _Tables = 
		SELECTCOLUMNS(
			INFO.TABLES(),
			"TABLE", [Name],
			"Table ID", [ID]
		)

	VAR _ReferencedTables = 
		SELECTCOLUMNS(
			INFO.TABLES(),
			"REFERENCED_TABLE", [Name],
			"Referenced Table ID", [ID]
		)

	VAR _CombinedWithTables =
		NATURALLEFTOUTERJOIN(
			_Dependencies,
			_Tables
		)

	VAR _CombinedWithReferencedTables =
		NATURALLEFTOUTERJOIN(
			_CombinedWithTables,
			_ReferencedTables
		)

	RETURN
		SELECTCOLUMNS(
			_CombinedWithReferencedTables,
			"Object Type", [OBJECT_TYPE],
			"Table", [TABLE],
			"Object", [OBJECT],
			"Referenced Object Type", [REFERENCED_OBJECT_TYPE],
			"Referenced Table", [REFERENCED_TABLE],
			"Referenced Object", [REFERENCED_OBJECT]
		)
	ORDER BY [TABLE], [OBJECT]

Se også

  • Last updated on