INFO. PERSPEKTIVKOLONNER

Gælder for: beregnet kolonne beregnet tabel måling visuel beregning DAX forespørgsel

Returnerer en tabel med oplysninger om hver perspektivkolonne i den semantiske model. Denne funktion indeholder metadata om kolonner, der er inkluderet i perspektiver.

Syntaks

INFO.PERSPECTIVECOLUMNS ( [<Restriction name>, <Restriction value>], ... )

Parametre

Parametre er valgfrie for denne DAX funktion. Når der bruges parametre, skal begge angives. Mere end ét par parametre er tilladt. Begrænsningsnavnet og -værdien er tekst og indtastet i dobbelte anførselstegn.

Periode Definition
Begrænsningsnavn Navnet på den begrænsning, der bruges til at filtrere resultaterne.
Begrænsningsværdi Værdi, der bruges til at filtrere resultaterne af begrænsningen.

Restriktioner

Normalt kan alle kolonner i resultaterne af DAX-funktionen bruges som en begrænsning. Yderligere begrænsninger kan også være tilladt.

Returværdi

En tabel med følgende kolonner:

Column Betegnelse
[ID] Entydigt id for perspektivkolonnen
[PerspectiveTableID] Id for den perspektivtabel, der indeholder denne kolonne
[ColumnID] Id for den kolonne, der er inkluderet i perspektivet
[ModifiedTime] Tidsstempel for, hvornår perspektivkolonnen senest blev ændret

Bemærkninger

  • Bruges typisk i DAX forespørgsler til at undersøge og dokumentere modelmetadata.
  • Tilladelser, der kræves, afhænger af værten. Det kan kræve modeladministratortilladelser at forespørge om komplette metadata.

Eksempel

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	INFO.PERSPECTIVECOLUMNS()

Eksempel 2 – DAX forespørgsel med joinforbindelser

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	VAR _PerspectiveColumns =
		SELECTCOLUMNS(
			INFO.PERSPECTIVECOLUMNS(),
			"PerspectiveColumnID", [ID],
			"PerspectiveTableID", [PerspectiveTableID],
			"ColumnID", [ColumnID]
		)
	VAR _Columns = 
		SELECTCOLUMNS(
			INFO.COLUMNS(),
			"ColumnID", [ID],
			"Column Name", [ExplicitName],
			"TableID", [TableID]
		)
	VAR _Tables = 
		SELECTCOLUMNS(
			INFO.TABLES(),
			"TableID", [ID],
			"Table Name", [Name]
		)
	VAR _CombinedTable1 =
		NATURALLEFTOUTERJOIN(
			_PerspectiveColumns,
			_Columns
		)
	VAR _CombinedTable2 =
		NATURALLEFTOUTERJOIN(
			_CombinedTable1,
			_Tables
		)
	RETURN
		SELECTCOLUMNS(
			_CombinedTable2,
			"Table Name", [Table Name],
			"Column Name", [Column Name]
		)
	ORDER BY [Table Name], [Column Name]

Se også

  • Last updated on