INFO. VARIATIONER

Gælder for: beregnet kolonne beregnet tabel måling visuel beregning DAX forespørgsel

Returnerer en tabel med oplysninger om alle variationer i den semantiske model. Disse oplysninger hjælper dig med at forstå modellen.

Syntaks

INFO.VARIATIONS([<Restriction name>, <Restriction value>], ...)

Parametre

Parametre er valgfrie for denne DAX funktion. Når der bruges parametre, skal begge angives. Mere end ét par parametre er tilladt. Begrænsningsnavnet og -værdien er tekst og indtastet i dobbelte anførselstegn.

Periode Definition
Begrænsningsnavn Navnet på den begrænsning, der bruges til at filtrere resultaterne.
Begrænsningsværdi Værdi, der bruges til at filtrere resultaterne af begrænsningen.

Restriktioner

Normalt kan alle kolonner i resultaterne af DAX-funktionen bruges som en begrænsning. Yderligere begrænsninger kan også være tilladt.

Returværdi

En tabel med følgende kolonner:

Column Betegnelse
[ID] En reference til objektet. Id'er genereres normalt automatisk og bør ikke ændres, når modellen er oprettet. Datatypen er ikke signeret lang (4 byte).
[ColumnID] En reference til det objekt, der ejer denne variation.
[Navn] Navnet på variationen, der bruges i kode, script og forespørgsler.
[Beskrivelse] Beskrivelsen af variationen.
[Relations-id] Id'et for den relation, som variationen er defineret for.
[DefaultHierarchyID] Id'et for standardhierarkiet for variationen.
[DefaultColumnID] Id'et for standardkolonnen for variationen.
[IsDefault] En True- eller False-indikator, der angiver, om variationen er standard.

Bemærkninger

Kan kun køres af brugere med skrivetilladelse til den semantiske model og ikke, når de har direkte forbindelse til den semantiske model i Power BI Desktop. Denne funktion kan bruges i DAX forespørgslerog kan ikke bruges i beregninger.

Eksempel 1 – DAX forespørgsel

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	INFO.VARIATIONS()

Denne DAX forespørgsel returnerer en tabel med alle kolonnerne i denne DAX funktion.

Eksempel 2 – DAX forespørgsel med joinforbindelser

Følgende DAX forespørgsel kan køres i DAX forespørgselsvisning:

EVALUATE
	VAR _INFO =
	INFO.VARIATIONS()

	VAR _ModelColumns = 
		SELECTCOLUMNS(
			INFO.COLUMNS(),
			"ColumnID", [ID],
			"Column Name", [ExplicitName]
		)
	VAR _ModelColumns2 = 
		SELECTCOLUMNS(
			INFO.COLUMNS(),
			"DefaultColumnID", [ID],
			"Default Column Name", [ExplicitName]
		)
	VAR _ModelRelationships = 
		SELECTCOLUMNS(
			INFO.RELATIONSHIPS(),
			"RelationshipID", [ID],
			"Relationship Name", [Name]
		)
	VAR _ModelHierarchies = 
		SELECTCOLUMNS(
			INFO.HIERARCHIES(),
			"DefaultHierarchyID", [ID],
			"Default Hierarchy Name", [Name]
		)
	

	VAR _CombinedTable2 =
	NATURALLEFTOUTERJOIN(
		_INFO,
		_ModelColumns
	)
	VAR _CombinedTable3 =
	NATURALLEFTOUTERJOIN(
		_CombinedTable2,
		_ModelColumns2
	)
	
	VAR _CombinedTable4 = 
	NATURALLEFTOUTERJOIN(
		_CombinedTable3,
		_ModelRelationships
	)
	
	VAR _CombinedTable5 = 
	NATURALLEFTOUTERJOIN(
		_CombinedTable4,
		_ModelHierarchies
	)

	RETURN
		SELECTCOLUMNS(
			_CombinedTable5,
			"Variation name", [Name],
			"Variation description", [Description],
			"Column Name", [Column Name],
			"Default Column Name", [Default Column Name],
			"Relationship Name", [Relationship Name],
			"Default Hierarchy Name", [Default Hierarchy Name]
		)
	ORDER BY [Variation name]

Denne DAX forespørgsel returnerer en tabel med kun de angivne kolonner og slutter sig til andre INFO-funktioner DAX og variationstabellen.

Se også

  • Last updated on