INFO. ANMERKUNGEN

Gilt für: Berechnete Spalte Berechnete Tabelle Measure Visuelle Berechnung DAX Abfrage

Gibt eine Tabelle mit Informationen zu jeder Anmerkung im Semantikmodell zurück. Diese Informationen helfen Ihnen, das Modell zu verstehen.

Syntax

INFO.ANNOTATIONS ( [<Restriction name>, <Restriction value>], ... )

Parameter

Parameter sind für diese DAX Funktion optional. Wenn Parameter verwendet werden, müssen beide angegeben werden. Es sind mehrere Parameterpaare zulässig. Der Einschränkungsname und -wert sind Text und werden in doppelte Anführungszeichen eingegeben.

Ausdruck Definition
Einschränkungsname Name der Einschränkung, die zum Filtern der Ergebnisse verwendet wird.
Einschränkungswert Wert, der zum Filtern der Ergebnisse der Einschränkung verwendet wird.

Einschränkungen

In der Regel können alle Spalten der DAX Funktionsergebnisse als Einschränkung verwendet werden. Weitere Einschränkungen können ebenfalls zulässig sein.

Rückgabewert

Eine Tabelle mit den folgenden Spalten:

Spalte Beschreibung
[ID] Ein Verweis auf das Objekt. IDs werden in der Regel automatisch generiert und sollten nicht geändert werden, nachdem das Modell erstellt wurde. Der Datentyp ist nicht signiert (4 Byte).
[ObjectID] Ein Verweis auf das Objekt, das diese Anmerkung besitzt.
[ObjectType] Ein Verweis auf den Objekttyp, der diese Anmerkung besitzt.
[Name] Der Name des Objekts, das in Code, Skript und Abfragen verwendet wird.
[Wert] Der Wert der Anmerkung.
[ModifiedTime] Die Uhrzeit, zu der das Objekt zuletzt geändert wurde.

Bemerkungen

Kann nur von Benutzern mit Schreibberechtigung für das Semantikmodell und nicht ausgeführt werden, wenn live mit dem Semantikmodell in Power BI Desktop verbunden ist. Diese Funktion kann in DAX Abfragenverwendet werden und kann nicht in Berechnungen verwendet werden.

Beispiel 1 – DAX Abfrage

Die folgende DAX Abfrage kann in DAX Abfrageansichtausgeführt werden:

EVALUATE
	INFO.ANNOTATIONS()

Diese DAX Abfrage gibt eine Tabelle mit allen Spalten dieser DAX-Funktion zurück.

Beispiel 2 – DAX Abfrage mit Verknüpfungen

Die folgende DAX Abfrage kann in DAX Abfrageansichtausgeführt werden:

EVALUATE
	VAR _ObjectTypeEnum =
	DATATABLE(
	"ObjectType",INTEGER,
	"Object",STRING,
	{
	{0,"Null"},
	{1,"Model"},
	{2,"DataSource"},
	{3,"Table"},
	{4,"Column"},
	{5,"AttributeHierarchy"},
	{6,"Partition"},
	{7,"Relationship"},
	{8,"Measure"},
	{9,"Hierarchy"},
	{10,"Level"},
	{11,"Annotation"},
	{12,"KPI"},
	{13,"Culture"},
	{14,"ObjectTranslation"},
	{15,"LinguisticMetadata"},
	{29,"Perspective"},
	{30,"PerspectiveTable"},
	{31,"PerspectiveColumn"},
	{32,"PerspectiveHierarchy"},
	{33,"PerspectiveMeasure"},
	{34,"Role"},
	{35,"RoleMembership"},
	{36,"TablePermission"},
	{37,"Variation"},
	{38,"Set"},
	{39,"PerspectiveSet"},
	{40,"ExtendedProperty"},
	{41,"Expression"},
	{42,"ColumnPermission"},
	{43,"DetailRowsDefinition"},
	{44,"RelatedColumnDetails"},
	{45,"GroupByColumn"},
	{46,"CalculationGroup"},
	{47,"CalculationItem"},
	{48,"AlternateOf"},
	{49,"RefreshPolicy"},
	{50,"FormatStringDefinition"}
	}
	)

	VAR _INFO =
	INFO.ANNOTATIONS()

	VAR _CombinedTable =
	NATURALLEFTOUTERJOIN(
		_INFO,
		_ObjectTypeEnum
	)

	VAR _ModelObjects =
	UNION(
		SELECTCOLUMNS(
			INFO.MEASURES(),
			"ObjectID", [ID],
			"Object Name", [Name]
		),
		SELECTCOLUMNS(
			INFO.TABLES(),
			"ObjectID", [ID],
			"Object Name", [Name]
		),
		SELECTCOLUMNS(
			INFO.COLUMNS(),
			"ObjectID", [ID],
			"Object Name", [ExplicitName]
		),
		SELECTCOLUMNS(
			INFO.EXPRESSIONS(),
			"ObjectID", [ID],
			"Object Name", [Name]
		),
		SELECTCOLUMNS(
			INFO.MODEL(),
			"ObjectID", [ID],
			"Object Name", [Name]
		)
	)

	VAR _CombinedTable2 =
	NATURALLEFTOUTERJOIN(
		_CombinedTable,
		_ModelObjects
	)

	RETURN
		SELECTCOLUMNS(
			_CombinedTable2,
			"Object type", [Object],
			"Object", [Object Name],
			"Annotation name", [Name],
			"Annotation value", [Value]
		)
	ORDER BY [Annotation name]

Diese DAX Abfrage gibt eine Tabelle zurück, die nur die angegebenen Spalten enthält und mit anderen INFO-DAX Funktionen und der Enumerationstabelle verknüpfen.

Aufzählungen

Spalten, die in dieser INFO-Funktion zurückgegeben werden, geben die ID einer Aufzählung oder Nachschlagetabelle an. Hier sind die Werte für jede Enumeration in dieser DAX Funktion.

ObjectType

Zahl Wert
0 Null
1 Modell
2 Datenquelle
3 Tisch
4 Spalte
5 AttributeHierarchy
6 Trennwand
7 Beziehung
8 Messen
9 Hierarchie
10 Niveau
11 Anmerkung
12 KPI
13 Kultur
14 ObjectTranslation
15 LinguisticMetadata
29 Perspektive
30 PerspectiveTable
31 PerspectiveColumn
32 PerspectiveHierarchy
33 PerspectiveMeasure
34 Rolle
35 RoleMembership
36 TablePermission
37 Variation
38 Garnitur
39 PerspectiveSet
40 ExtendedProperty
41 Ausdruck
42 ColumnPermission
43 DetailRowsDefinition
44 RelatedColumnDetails
45 GroupByColumn
46 CalculationGroup
47 CalculationItem
48 AlternateOf
49 RefreshPolicy
50 FormatStringDefinition

Diese Tabelle basiert auf der offiziellen Dokumentation.

Um mit INFO-Funktionen zu verbinden, verwenden Sie diese DAX Abfrage.

EVALUATE
	DATATABLE(
	"ObjectType",INTEGER,
	"Object",STRING,
	{
	{0,"Null"},
	{1,"Model"},
	{2,"DataSource"},
	{3,"Table"},
	{4,"Column"},
	{5,"AttributeHierarchy"},
	{6,"Partition"},
	{7,"Relationship"},
	{8,"Measure"},
	{9,"Hierarchy"},
	{10,"Level"},
	{11,"Annotation"},
	{12,"KPI"},
	{13,"Culture"},
	{14,"ObjectTranslation"},
	{15,"LinguisticMetadata"},
	{29,"Perspective"},
	{30,"PerspectiveTable"},
	{31,"PerspectiveColumn"},
	{32,"PerspectiveHierarchy"},
	{33,"PerspectiveMeasure"},
	{34,"Role"},
	{35,"RoleMembership"},
	{36,"TablePermission"},
	{37,"Variation"},
	{38,"Set"},
	{39,"PerspectiveSet"},
	{40,"ExtendedProperty"},
	{41,"Expression"},
	{42,"ColumnPermission"},
	{43,"DetailRowsDefinition"},
	{44,"RelatedColumnDetails"},
	{45,"GroupByColumn"},
	{46,"CalculationGroup"},
	{47,"CalculationItem"},
	{48,"AlternateOf"},
	{49,"RefreshPolicy"},
	{50,"FormatStringDefinition"}
	}
	)

Siehe auch

  • Last updated on