Resultados

El Result<'T,'TFailure> tipo permite escribir código tolerante a errores que se puede componer.

Sintaxis

// The definition of Result in FSharp.Core
[<StructuralEquality; StructuralComparison>]
[<CompiledName("FSharpResult`2")>]
[<Struct>]
type Result<'T,'TError> =
    | Ok of ResultValue:'T
    | Error of ErrorValue:'TError

Observaciones

Consulte el Result módulo de los combinadores integrados para Result. tipo.

Tenga en cuenta que el tipo de resultado es una unión discriminada por estructura. La semántica de igualdad estructural se aplica aquí.

El Result tipo se usa normalmente en el control de errores monádico, que a menudo se conoce como Programación orientada a ferrocarril dentro de la comunidad de F#. En el ejemplo trivial siguiente se muestra este enfoque.

// Define a simple type which has fields that can be validated
type Request =
    { Name: string
      Email: string }

// Define some logic for what defines a valid name.
//
// Generates a Result which is an Ok if the name validates;
// otherwise, it generates a Result which is an Error.
let validateName req =
    match req.Name with
    | null -> Error "No name found."
    | "" -> Error "Name is empty."
    | "bananas" -> Error "Bananas is not a name."
    | _ -> Ok req

// Similarly, define some email validation logic.
let validateEmail req =
    match req.Email with
    | null -> Error "No email found."
    | "" -> Error "Email is empty."
    | s when s.EndsWith("bananas.com") -> Error "No email from bananas.com is allowed."
    | _ -> Ok req

let validateRequest reqResult =
    reqResult
    |> Result.bind validateName
    |> Result.bind validateEmail

let test() =
    // Now, create a Request and pattern match on the result.
    let req1 = { Name = "Phillip"; Email = "phillip@contoso.biz" }
    let res1 = validateRequest (Ok req1)
    match res1 with
    | Ok req -> printfn $"My request was valid! Name: {req.Name} Email {req.Email}"  
    | Error e -> printfn $"Error: {e}"
    // Prints: "My request was valid!  Name: Phillip Email: phillip@consoto.biz"

    let req2 = { Name = "Phillip"; Email = "phillip@bananas.com" }
    let res2 = validateRequest (Ok req2)
    match res2 with
    | Ok req -> printfn $"My request was valid! Name: {req.Name} Email {req.Email}"  
    | Error e -> printfn $"Error: {e}"
    // Prints: "Error: No email from bananas.com is allowed."

test()

Como puede ver, es bastante fácil encadenar varias funciones de validación si los obliga a devolver un Result. Esto le permite dividir la funcionalidad como esta en pequeños fragmentos que son tan componebles como los necesita. Esto también tiene el valor añadido de aplicar el uso de la coincidencia de patrones al final de una ronda de validación, que a su vez exige un mayor grado de corrección del programa.

Consulte también

  • Last updated on