Visual khusus dasbor

Semua visualisasi yang Anda buat dalam konteks operator render tersedia dalam visualisasi dasbor. Namun, visualisasi berikut ini hanya tersedia di dasbor Azure Data Explorer, dasbor Real-Time, atau antarmuka pengguna web Azure Data Explorer, dan tidak tersedia dengan menggunakan operator render.

Untuk mempelajari cara mengkustomisasi visual dasbor apa pun, lihat Mengkustomisasi visual dasbor Azure Data Explorer

Untuk informasi umum tentang dasbor di Azure Data Explorer, lihat Memvisualisasikan data dengan dasbor Azure Data Explorer.

Bagan corong

Bagan corong memvisualisasikan proses linier yang memiliki tahapan terhubung berurutan. Setiap tahap corong mewakili persentase dari total. Dalam kebanyakan kasus, bagan corong berbentuk seperti corong, dengan tahap pertama menjadi yang terbesar, dan setiap tahap berikutnya lebih kecil dari pendahulunya.

Contoh berikut memvisualisasikan perkembangan permintaan server, memperlihatkan jumlah total sesi, permintaan, dan status penyelesaiannya. Ini menyoroti penurunan dari sesi menuju permintaan dan proporsi permintaan yang selesai dibandingkan dengan permintaan yang tidak lengkap.

Kueri contoh

let stageOrder = datatable(Stage:string, Order:int)
[
    "session_id", 1,
    "request_id", 2,
    "Completed", 3,
    "Incomplete", 4
];

let base = TransformedServerMetrics
| where MetricType == "sqlserver_requests";

// Build the funnel table dynamically
let funnelData = 
    union 
    (base | where SQLMetrics == "session_id" | summarize Count = count() | extend Stage = "session_id"),
    (base | where SQLMetrics == "request_id" | summarize Count = count() | extend Stage = "request_id"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value == 100) | extend Stage = "Completed"),
    (base | where SQLMetrics == "percent_complete" 
          | summarize Count = countif(Value < 100) | extend Stage = "Incomplete");

// Join with stage order and order properly
funnelData
| join kind=inner stageOrder on Stage
| order by Order asc
| project Stage, Count

Peta panas

Peta panas menunjukkan nilai untuk variabel minat utama di dua variabel sumbu sebagai kisi kotak berwarna.

Untuk merender peta panas, kueri harus menghasilkan tabel dengan tiga kolom. Data yang digunakan untuk bidang nilai harus numerik. Kolom yang Anda gunakan untuk nilai x dan y harus mengikuti aturan ini:

• Jika nilai dalam kolom x dalam string format , nilai dalam kolom y juga harus dalam string format .
• Jika nilai dalam kolom x dalam datetime format , nilai di kolom y harus numerik.

Contoh berikut menunjukkan distribusi lima metrik SQL yang paling sering di berbagai jenis metrik. Ini menyoroti jenis metrik mana yang paling umum untuk setiap metrik SQL, sehingga mudah untuk mengidentifikasi pola aktivitas di metrik teratas.

Kueri contoh

let topMetrics = TransformedServerMetrics
| summarize TotalCount = count() by SQLMetrics
| top 5 by TotalCount;  // pick only the 5 most common metrics
TransformedServerMetrics
| where SQLMetrics in (topMetrics | project SQLMetrics)
| summarize Count = count() by SQLMetrics, MetricType
| project X = MetricType, Y = SQLMetrics, Value = Count