Mulai cepat: Menyebarkan sumber daya Azure pertama Anda dengan penyedia AzAPI Terraform

Terraform memungkinkan definisi, pratinjau, dan penyebaran infrastruktur cloud. Dengan menggunakan Terraform, Anda membuat file konfigurasi menggunakan sintaks HCL. Sintaksis HCL memungkinkan Anda menentukan penyedia cloud - seperti Azure - dan elemen yang membentuk infrastruktur cloud Anda. Setelah membuat file konfigurasi, Anda membuat rencana eksekusi yang memungkinkan Anda mempratinjau perubahan infrastruktur sebelum disebarkan. Setelah memverifikasi perubahan, Anda menerapkan rencana eksekusi untuk menyebarkan infrastruktur.

Penyedia AzAPI Terraform mengelola sumber daya Azure langsung melalui API Azure Resource Manager. Ini sangat berguna untuk sumber daya, properti, atau versi API yang belum didukung oleh AzureRM. Dalam contoh ini, Anda menggunakan azapi_resource untuk membuat Azure Container Registry.

Prasyarat

• Langganan Azure: Jika Anda tidak memiliki langganan Azure, buat akun gratis sebelum Memulai.

• Konfigurasikan Terraform: Jika Anda belum melakukannya, konfigurasikan Terraform menggunakan salah satu opsi berikut:

  • Mengonfigurasi Terraform di Azure Cloud Shell dengan Bash
  • Mengonfigurasi Terraform di Azure Cloud Shell dengan PowerShell
  • Mengonfigurasi Terraform di Windows dengan Bash
  • Mengonfigurasi Terraform di Windows dengan PowerShell

Saat Anda masuk ke portal Microsoft Azure dengan akun Microsoft, langganan Azure default untuk akun tersebut digunakan.

Terraform secara otomatis mengautentikasi menggunakan informasi dari langganan Azure default.

Jalankan az account show untuk memverifikasi akun Microsoft dan langganan Azure saat ini.

az account show

Setiap perubahan yang Anda buat melalui Terraform ada di langganan Azure yang ditampilkan. Jika itu yang Anda inginkan, lewati sisa artikel ini.

Menerapkan kode Terraform

1. Buat direktori untuk menguji dan menjalankan kode sampel Terraform dan menjadikannya direktori saat ini.

2. Buat file bernama providers.tf dan masukkan kode berikut:

   terraform {
     required_providers {
       azapi = {
         source = "Azure/azapi"
         version = "~>2.0"
       }
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "~>4.0"
       }
       random = {
         source  = "hashicorp/random"
         version = "~>3.0"
       }
     }
   }
   
   provider "azurerm" {
     features {}
   }
   

3. Buat file bernama variables.tf dan masukkan kode berikut:

   variable "resource_group_location" {
     type        = string
     default     = "eastus"
     description = "Location of the resource group."
   }
   
   variable "resource_group_name_prefix" {
     type        = string
     default     = "rg"
     description = "Prefix of the resource group name that's combined with a random ID so name is unique in your Azure subscription."
   }
   
   variable "container_registry_name" {
     type        = string
     default     = ""
     description = "Name of the container registry."
   }
   

4. Buat file bernama main.tf dan masukkan kode berikut:

   # Create a resource group with a random name.
   resource "random_pet" "rg_name" {
     prefix = var.resource_group_name_prefix
   }
   
   resource "azurerm_resource_group" "rg" {
     location = var.resource_group_location
     name     = random_pet.rg_name.id
   }
   
   # Create a user assigned identity resource.
   resource "azurerm_user_assigned_identity" "example" {
     name                = "example"
     resource_group_name = azurerm_resource_group.rg.name
     location            = azurerm_resource_group.rg.location
   }
   
   # Create a random name for the container registry.
   resource "random_string" "acr_name" {
     length  = 10
     special = false
     upper   = false
     numeric = false
   }
   
   # Manage a container registry resource.
   resource "azapi_resource" "example" {
     type      = "Microsoft.ContainerRegistry/registries@2020-11-01-preview"
     name      = coalesce(var.container_registry_name, random_string.acr_name.result)
     parent_id = azurerm_resource_group.rg.id
   
     location = azurerm_resource_group.rg.location
     identity {
       type         = "SystemAssigned, UserAssigned"
       identity_ids = [azurerm_user_assigned_identity.example.id]
     }
   
     body = {
       sku = {
         name = "Standard"
       }
       properties = {
         adminUserEnabled = true
       }
     }
   
     tags = {
       "Key" = "Value"
     }
   
     response_export_values = ["properties.loginServer", "properties.policies.quarantinePolicy.status"]
   }
   

5. Buat file bernama outputs.tf dan masukkan kode berikut:

   output "resource_group_name" {
     value = azurerm_resource_group.rg.name
   }
   
   output "azure_container_registry_name" {
     value = azapi_resource.example.name
   }
   

Inisialisasi Terraform

Jalankan terraform init untuk menginisialisasi penyebaran Terraform. Perintah ini mengunduh penyedia Azure yang diperlukan untuk mengelola sumber daya Azure Anda.

terraform init -upgrade

Poin-poin penting:

• Parameter -upgrade meningkatkan plugin penyedia yang diperlukan ke versi terbaru yang sesuai dengan batasan versi konfigurasi.

Buat rencana eksekusi Terraform

Jalankan terraform plan untuk membuat rencana eksekusi.

terraform plan -out main.tfplan

Poin-poin penting:

• Perintah terraform plan membuat rencana eksekusi, tetapi tidak menjalankannya. Perintah ini justru menentukan tindakan yang diperlukan untuk membuat konfigurasi yang ditentukan dalam file konfigurasi Anda. Pola ini memungkinkan Anda memastikan apakah rencana eksekusi telah sesuai dengan ekspektasi Anda sebelum membuat perubahan pada sumber daya aktual.
• Parameter -out opsional memungkinkan Anda menentukan file output untuk rencana. Menggunakan parameter -out memastikan bahwa rencana yang Anda tinjau benar-benar sesuai dengan yang diterapkan.

Terapkan rencana pelaksanaan Terraform

Jalankan terraform apply untuk menerapkan rencana pelaksanaan ke infrastruktur cloud Anda.

terraform apply main.tfplan

Poin-poin penting:

• Contoh terraform apply perintah mengasumsikan Anda sebelumnya menjalankan terraform plan -out main.tfplan.
• Jika Anda menentukan nama file yang berbeda untuk parameter -out, gunakan nama file yang sama dalam panggilan ke terraform apply.
• Jika Anda tidak menggunakan parameter -out, panggil terraform apply tanpa parameter apa pun.

Memverifikasi hasil

Membersihkan sumber daya

Ketika Anda tidak lagi membutuhkan sumber daya yang dibuat melalui Terraform, lakukan langkah-langkah berikut:

1. Jalankan terraform plan dan tentukan destroy flag.

   terraform plan -destroy -out main.destroy.tfplan
   

   Poin-poin penting:

   • Perintah terraform plan membuat rencana eksekusi, tetapi tidak menjalankannya. Perintah ini justru menentukan tindakan yang diperlukan untuk membuat konfigurasi yang ditentukan dalam file konfigurasi Anda. Pola ini memungkinkan Anda memastikan apakah rencana eksekusi telah sesuai dengan ekspektasi Anda sebelum membuat perubahan pada sumber daya aktual.
   • Parameter -out opsional memungkinkan Anda menentukan file output untuk rencana. Menggunakan parameter -out memastikan bahwa rencana yang Anda tinjau benar-benar sesuai dengan yang diterapkan.

2. Jalankan terraform terapkan untuk menerapkan rencana eksekusi.

   terraform apply main.destroy.tfplan
   

Memecahkan masalah Terraform pada Azure

Memecahkan masalah umum saat menggunakan Terraform di Azure

Langkah berikutnya