Praktik terbaik FinOps untuk Web

Artikel ini menguraikan kumpulan praktik FinOps yang terbukti untuk layanan web. Ini menyediakan strategi untuk mengoptimalkan biaya, meningkatkan efisiensi, dan menggunakan kueri Azure Resource Graph (ARG) untuk mendapatkan wawasan tentang sumber daya web Anda. Dengan mengikuti praktik ini, Anda dapat memastikan bahwa layanan web Anda hemat biaya dan selaras dengan tujuan keuangan organisasi Anda.


App Service

Bagian berikut ini menyediakan kueri ARG untuk Layanan Aplikasi. Kueri ini membantu Anda mendapatkan wawasan tentang sumber daya App Service Anda dan memastikan sumber daya tersebut dikonfigurasi dengan pengaturan yang sesuai. Dengan menganalisis paket App Service dan menampilkan rekomendasi dari Azure Advisor, Anda dapat mengoptimalkan sumber daya App Service untuk efisiensi biaya yang lebih baik.

Kueri: Status Aplikasi Web

Kueri ARG ini mengambil status dan informasi dasar aplikasi web dalam lingkungan Azure Anda.

Kategori

Pemantauan

Pertanyaan

resources
| where type =~ 'Microsoft.Web/sites'
| project
    id,
    WebAppName = name,
    Type = kind,
    Status = tostring(properties.state),
    WebAppLocation = location,
    AppServicePlan = tostring(properties.serverFarmId),
    WebAppRG = resourceGroup,
    SubscriptionId = subscriptionId
| order by id asc

Menghapus paket App Service kosong

Rekomendasi: Hapus paket App Service yang tidak memiliki aplikasi atau fungsi yang dihosting untuk menghindari biaya yang tidak perlu.

Tentang paket App Service kosong

Paket App Service menentukan sumber daya komputasi untuk aplikasi web Anda. Paket berbayar dikenakan biaya berdasarkan SKU dan jumlah instans yang dikonfigurasi, terlepas dari apakah ada aplikasi yang dihosting di dalamnya. Paket kosong dapat menumpuk selama pengembangan atau saat aplikasi dipindahkan dari satu paket ke paket lain. Menghapus rencana yang tidak digunakan menghilangkan biaya yang tidak perlu.

Note

Hub FinOps dapat secara otomatis mengidentifikasi paket App Service kosong. Pelajari lebih lanjut.

Mengidentifikasi paket App Service kosong

Gunakan kueri ARG berikut untuk mengidentifikasi paket App Service tanpa aplikasi yang dihosting.

resources
| where type =~ 'microsoft.web/serverfarms'
| where toint(properties.numberOfSites) == 0
| where sku.tier !~ 'Free'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Kueri: Rincian rencana App Service

Kueri ARG ini mengambil informasi terperinci tentang Paket Azure App Service dalam lingkungan Azure Anda.

Kategori

Manajemen sumber daya

Pertanyaan

resources
| where type == "microsoft.web/serverfarms"  and sku.tier !~ 'Free'
| project
    planId = tolower(tostring(id)),
    name,
    skuname = tostring(sku.name),
    skutier = tostring(sku.tier),
    workers = tostring(properties.numberOfWorkers),
    maxworkers = tostring(properties.maximumNumberOfWorkers),
    webRG = resourceGroup,
    Sites = tostring(properties.numberOfSites),
    SubscriptionId = subscriptionId
| join kind=leftouter (
    resources
    | where type == "microsoft.insights/autoscalesettings"
    | project
        planId = tolower(tostring(properties.targetResourceUri)),
        PredictiveAutoscale = properties.predictiveAutoscalePolicy.scaleMode,
        AutoScaleProfiles = properties.profiles,
        resourceGroup
) on planId

Berikan umpan balik

Beri tahu kami bagaimana kinerja kami melalui ulasan singkat. Kami menggunakan ulasan ini untuk meningkatkan dan memperluas alat dan sumber daya FinOps.

Berikan umpan balik

Jika Anda mencari sesuatu yang spesifik, pilih yang sudah ada atau buat ide baru. Bagikan ide dengan orang lain untuk mendapatkan lebih banyak suara. Kami fokus pada ide-ide dengan suara terbanyak.

Memilih atau menyarankan ide


Konten terkait

Sumber daya terkait:

Solusi terkait:


  • Last updated on