Najlepsze rozwiązania dotyczące sieci w usłudze FinOps

W tym artykule opisano sprawdzone rozwiązania FinOps dotyczące usług sieciowych. Koncentrują się na optymalizacji kosztów, ulepszeniach wydajności i szczegółowych informacji o zasobach.


Azure Firewall

W poniższych sekcjach przedstawiono zapytania usługi Azure Resource Graph (ARG) dla usługi Azure Firewall. Te zapytania ułatwiają uzyskanie wglądu w zasoby usługi Azure Firewall i upewnienie się, że zostały skonfigurowane przy użyciu odpowiednich ustawień. Analizując wzorce użycia i rekomendacje od usługi Azure Advisor, możesz zoptymalizować konfiguracje zapory platformy Azure pod kątem efektywności kosztowej.

Zapytanie: Analiza zapory platformy Azure i zasad zapory

Zapytanie ARG analizuje zapory Azure i przypisane do nich zasady zapory w twoim środowisku Azure. Dotyczy to w szczególności zapór ogniowych z poziomem Premium SKU i sprawdza, czy konfiguracje w skojarzonych politykach zapory korzystają z funkcji dostępnych w warstwie Premium.

Kategoria

Optymalizacja

Zapytanie

resources
| where type =~ 'Microsoft.Network/azureFirewalls' and properties.sku.tier=="Premium"
| project FWID=id, firewallName=name, SkuTier=tostring(properties.sku.tier), resourceGroup, location
| join kind=inner (
    resources
    | where type =~ 'microsoft.network/firewallpolicies'
    | mv-expand properties.firewalls
    | extend intrusionDetection = tostring(properties.intrusionDetection contains "Alert"
        or properties.intrusionDetection contains "Deny")
    | extend transportSecurity = tostring(properties.transportSecurity contains "keyVaultSecretId")
    | extend FWID = tostring(properties_firewalls.id)
    | where intrusionDetection == "False"
        and transportSecurity == "False"
    | project
        PolicyName = name,
        PolicySKU = tostring(properties.sku.tier),
        intrusionDetection,
        transportSecurity,
        FWID
) on FWID

Zapytanie: Analiza usługi Azure Firewall i skojarzonych podsieci

To zapytanie usługi ARG analizuje zapory platformy Azure i skojarzone z nimi podsieci w środowisku platformy Azure. Daje wgląd w to, które podsieci są skojarzone z każdym wystąpieniem zapory Azure. Zoptymalizuj użycie usługi Azure Firewall, używając centralnej instancji usługi Azure Firewall w sieci wirtualnej koncentratora lub centrum zabezpieczeń Virtual WAN. Następnie współużytkuj tę samą zaporę w wielu sieciach wirtualnych typu szprychy, które są połączone z tym samym koncentratorem w tej samej lokalizacji.

Kategoria

Optymalizacja

Zapytanie

resources
| where type =~ 'Microsoft.Network/azureFirewalls' and properties.sku.tier=="Premium"
| project
    FWID=id,
    firewallName=name,
    SkuTier=tostring(properties.sku.tier),
    resourceGroup,
    location
| join kind=inner (
    resources
    | where type =~ 'microsoft.network/firewallpolicies'
    | mv-expand properties.firewalls
    | extend intrusionDetection = tostring(properties.intrusionDetection contains "Alert"
        or properties.intrusionDetection contains "Deny")
    | extend transportSecurity = tostring(properties.transportSecurity contains "keyVaultSecretId")
    | extend FWID=tostring(properties_firewalls.id)
    | where intrusionDetection == "False"
        and transportSecurity == "False"
    | project
        PolicyName = name,
        PolicySKU = tostring(properties.sku.tier),
        intrusionDetection,
        transportSecurity,
        FWID
) on FWID

Application Gateway

Azure Application Gateway to moduł równoważenia obciążenia ruchu internetowego, który umożliwia zarządzanie ruchem kierowanym do aplikacji internetowych. Udostępnia ona usługi routingu i równoważenia obciążenia na poziomie aplikacji, które umożliwiają tworzenie skalowalnego i wysoce dostępnego frontonu internetowego w Azure.

Powiązane zasoby:

Usuwanie bezczynnych bram aplikacji

Zalecenie: Usuń bramy aplikacji, które nie mają żadnych pul zaplecza, aby uniknąć niepotrzebnych kosztów.

Informacje o bezczynnych bramach aplikacji

Bramy aplikacji bez żadnych elementów docelowych puli zaplecza nie kierują aktywnie ruchu i mogą oznaczać nieużywane zasoby. Te bezczynne bramy nadal generują koszty, mimo że nie pełnią żadnej funkcji.

Note

Centra FinOps mogą automatycznie identyfikować bezczynne bramy aplikacji. Dowiedz się więcej.

Identyfikowanie bezczynnych bram aplikacji

Użyj następującego zapytania usługi ARG, aby zidentyfikować bramy aplikacji z pustymi pulami zaplecza.

resources
| where type =~ 'Microsoft.Network/applicationGateways'
| extend
    backendPoolsCount = array_length(properties.backendAddressPools),
    SKUName = tostring(properties.sku.name),
    SKUTier = tostring(properties.sku.tier),
    SKUCapacity = properties.sku.capacity,
    backendPools = properties.backendAddressPools,
    resourceGroup = strcat('/subscriptions/',subscriptionId,'/resourceGroups/',resourceGroup)
| project id, name, SKUName, SKUTier, SKUCapacity, resourceGroup, subscriptionId
| join (
    resources
    | where type =~ 'Microsoft.Network/applicationGateways'
    | mvexpand backendPools = properties.backendAddressPools
    | extend backendIPCount = array_length(backendPools.properties.backendIPConfigurations)
    | extend backendAddressesCount = array_length(backendPools.properties.backendAddresses)
    | extend backendPoolName = backendPools.properties.backendAddressPools.name
    | summarize
        backendIPCount = sum(backendIPCount),
        backendAddressesCount = sum(backendAddressesCount)
        by id
) on id
| project-away id1
| where (backendIPCount == 0 or isempty(backendIPCount))
    and (backendAddressesCount==0 or isempty(backendAddressesCount))
| order by id asc

Uaktualnianie klasycznych bram aplikacji

Zalecenie: Uaktualnij jednostkę SKU usługi Application Gateway w wersji 1 do wersji 2 przed datą wycofania wersji 1, aby zachować obsługę i dostęp do ulepszonych funkcji.

Informacje o klasycznych bramach aplikacji

Application Gateway v1 SKU (Standard i WAF) zostaje wycofana. Jednostka SKU v2 oferuje automatyczne skalowanie, nadmiarowość strefową i lepszą wydajność. Migracja do wersji 2 zapewnia ciągłą obsługę i może obniżyć koszty dzięki skalowaniu automatycznemu, co automatycznie dostosowuje liczbę wystąpień na podstawie ruchu.

Note

Centra FinOps mogą automatycznie identyfikować klasyczne bramy aplikacji korzystające z jednostki SKU w wersji v1. Dowiedz się więcej.

Identyfikowanie klasycznych bram aplikacji

Użyj następującego zapytania ARG, aby zidentyfikować bramy aplikacji, które nadal używają jednostki SKU v1.

resources
| where type =~ 'microsoft.network/applicationgateways'
| where properties.sku.tier in ('Standard', 'WAF')
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUTier = tostring(properties.sku.tier),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

DDoS Protection

Azure ochrona przed atakami DDoS zapewnia środki zaradcze przed najbardziej zaawansowanymi zagrożeniami DDoS. Zapewnia ona ulepszone możliwości ograniczania ryzyka ataków DDoS dla aplikacji i zasobów wdrożonych w sieciach wirtualnych.

Powiązane zasoby:

Usuwanie niezwiązanych planów ochrony przed atakami DDoS

Zalecenie: Usuń plany ochrony przed atakami DDoS, które nie są skojarzone z żadną siecią wirtualną, aby uniknąć niepotrzebnych kosztów.

Informacje o niepowiązanych planach ochrony przed atakami DDoS

Plany ochrony przed atakami DDoS powodują naliczanie stałej opłaty miesięcznej. Plany, które nie są skojarzone z żadną siecią wirtualną, nie zapewniają żadnej ochrony, ale nadal generują koszty. Usunięcie nieużywanych planów eliminuje niepotrzebne wydatki.

Note

Centra FinOps mogą automatycznie identyfikować niezwiązane plany ochrony przed atakami DDoS. Dowiedz się więcej.

Identyfikowanie niezwiązanych planów ochrony przed atakami DDoS

Użyj następującego zapytania usługi ARG, aby zidentyfikować plany ochrony przed atakami DDoS, które nie są skojarzone z żadną siecią wirtualną.

resources
| where type =~ 'microsoft.network/ddosprotectionplans'
| where isnull(properties.virtualNetworks) or array_length(properties.virtualNetworks) == 0
| project
    ResourceId = tolower(id),
    ResourceName = name,
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

ExpressRoute

Azure ExpressRoute umożliwia rozszerzenie sieci lokalnych na chmurę Microsoft za pośrednictwem połączenia prywatnego. Obwody ExpressRoute podlegają miesięcznym opłatom w zależności od jednostki SKU i aprowizowanej przepustowości.

Powiązane zasoby:

Usuwanie nieprowizowanych obwodów usługi ExpressRoute

Zalecenie: Usuń lub aprowizuj obwody usługi ExpressRoute, które są w stanie nieaprowizowanym, aby uniknąć niepotrzebnych opłat.

Informacje o nieprowizowanych obwodach usługi ExpressRoute

Obwody ExpressRoute, które pozostają w stanie „NotProvisioned”, nie przenoszą aktywnie ruchu, ale nadal podlegają miesięcznym opłatom. Te łącza mogły zostać utworzone, ale nigdy nie zostały sfinalizowane u dostawcy usług. Identyfikowanie i usuwanie ich eliminuje niepotrzebne koszty.

Note

Centra FinOps mogą automatycznie identyfikować nieprowizowane obwody usługi ExpressRoute. Dowiedz się więcej.

Identyfikowanie nieaprowizowanych obwodów ExpressRoute

Użyj następującego zapytania ARG, aby zidentyfikować obwody ExpressRoute w stanie nieudostępnionym.

resources
| where type =~ 'Microsoft.Network/expressRouteCircuits'
    and properties.serviceProviderProvisioningState == "NotProvisioned"
| extend
    ServiceLocation = tostring(properties.serviceProviderProperties.peeringLocation),
    ServiceProvider = tostring(properties.serviceProviderProperties.serviceProviderName),
    BandwidthInMbps = tostring(properties.serviceProviderProperties.bandwidthInMbps)
| project
    ERId = id,
    ERName = name,
    ERRG = resourceGroup,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    SKUFamily = tostring(sku.family),
    ERLocation = location,
    ServiceLocation,
    ServiceProvider,
    BandwidthInMbps

Load Balancer

Azure Load Balancer działa w warstwie 4 modelu OSI i dystrybuuje ruch przychodzący między wystąpieniami puli zaplecza w dobrej kondycji. Zapewnia wysoką dostępność dzięki monitorowaniu stanu instancji zaplecza i automatycznemu przekierowywaniu ruchu z instancji w złym stanie.

Powiązane zasoby:

Usuwanie bezczynnych modułów równoważenia obciążenia

Zalecenie: Usuń moduły równoważenia obciążenia, które nie mają żadnych pul zaplecza, aby uniknąć niepotrzebnych kosztów.

Informacje o bezczynnych modułach równoważenia obciążenia

Moduły równoważenia obciążenia bez obiektów docelowych puli zaplecza nie rozdzielają aktywnie ruchu i mogą stanowić niewykorzystywane zasoby. Moduły równoważenia obciążenia jednostki SKU w warstwie Standardowa generują koszty nawet w przypadku bezczynności, więc usunięcie nieużywanych wystąpień może zmniejszyć niepotrzebne wydatki.

Note

Centra FinOps mogą automatycznie identyfikować bezczynne moduły równoważenia obciążenia. Dowiedz się więcej.

Identyfikowanie bezczynnych modułów równoważenia obciążenia

Użyj następującego zapytania ARG, aby zidentyfikować moduły równoważenia obciążenia w warstwie Standard z pustymi pulami zaplecza.

resources
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| extend SKUName = tostring(sku.name)
| extend SKUTier = tostring(sku.tier)
| extend location,backendAddressPools = properties.backendAddressPools
| where type =~ 'microsoft.network/loadbalancers'
    and array_length(backendAddressPools) == 0
    and sku.name!='Basic'
| order by id asc
| project
    id,
    name,
    SKUName,
    SKUTier,
    backendAddressPools,
    location,
    resourceGroup,
    subscriptionId

Uaktualnianie podstawowych modułów równoważenia obciążenia

Zalecenie: Uaktualnij moduły równoważenia obciążenia korzystające z wycofanej jednostki SKU Basic do jednostki SKU Standard, aby uzyskać lepszą wydajność, bezpieczeństwo i dalsze wsparcie.

Informacje o podstawowych modułach równoważenia obciążenia

Podstawowa jednostka SKU dla Azure Load Balancer została wycofana 30 września 2025 r. Podstawowe moduły równoważenia obciążenia nie zapewniają umowy SLA, nie obsługują stref dostępności i mają ograniczone możliwości diagnostyczne. Przejście na warstwę Standard zapewnia większą niezawodność, wyższą wydajność i lepsze zabezpieczenia.

Note

Centra FinOps mogą automatycznie identyfikować podstawowe moduły równoważenia obciążenia. Dowiedz się więcej.

Identyfikowanie podstawowych modułów równoważenia obciążenia

Użyj następującego zapytania ARG, aby zidentyfikować moduły równoważenia obciążenia korzystające z podstawowej jednostki SKU.

resources
| where type =~ 'microsoft.network/loadbalancers'
| where sku.name =~ 'Basic'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

NAT Gateway

Azure NAT Gateway zapewnia wychodzącą łączność internetową dla sieci wirtualnych. Bramy NAT upraszczają łączność z Internetem wyłącznie dla ruchu wychodzącego, zapewniając zarządzaną usługę SNAT o wysokiej dostępności.

Powiązane zasoby:

Usuń osierocone bramy NAT

Zalecenie: Usuń bramy NAT, które nie są skojarzone z żadną z podsieci, aby uniknąć niepotrzebnych opłat.

Informacje o osieroconych bramach NAT

Bramy NAT wiążą się z opłatami godzinowymi i kosztami przetwarzania danych. Bramy, które nie są skojarzone z żadną podsiecią, nie zapewniają łączności wychodzącej i reprezentują zmarnowane wydatki. Te osierocone bramy mogą pozostać po ponownej konfiguracji podsieci lub sieci wirtualnej.

Note

Centra FinOps mogą automatycznie identyfikować osierocone bramy NAT. Dowiedz się więcej.

Zidentyfikować osierocone bramy NAT

Użyj następującego zapytania ARG, aby zidentyfikować bramy NAT, które nie są skojarzone z żadną podsiecią.

resources
| where type == "microsoft.network/natgateways"
| where isnull(properties.subnets) or array_length(properties.subnets) == 0
| project
    id,
    GWName = name,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    Location = location,
    resourceGroup = tostring(strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)),
    subnets = properties.subnets,
    subscriptionId

Interfejs sieciowy

Azure interfejsy sieciowe umożliwiają Azure maszynom wirtualnym komunikowanie się z Internetem, Azure i zasobami lokalnymi. Karty sieciowe nie generują bezpośrednich opłat, ale osierocone karty sieciowe mogą wskazywać na pominięte działania porządkowe i komplikować zarządzanie zasobami.

Usuwanie niezałączanych interfejsów sieciowych

Zalecenie: Usuń interfejsy sieciowe, które nie są dołączone do żadnej maszyny wirtualnej ani prywatnego punktu końcowego, aby zapewnić czyste i mniejsze obciążenie związane z zarządzaniem środowiskiem.

Informacje o niezałączanych interfejsach sieciowych

Po usunięciu maszyny wirtualnej skojarzone z nią interfejsy sieciowe mogą nie być automatycznie czyszczone. Te oddzielone karty sieciowe mogą gromadzić się w czasie, zaśmiecając środowisko i potencjalnie zachowując skojarzone zasoby, takie jak publiczne adresy IP. Chociaż interfejsy sieciowe (NIC) nie generują bezpośrednich opłat, ich usunięcie upraszcza zarządzanie zasobami i może ujawnić inne osierocone zasoby.

Note

Koncentratory FinOps mogą automatycznie identyfikować nieprzyłączone interfejsy sieciowe. Dowiedz się więcej.

Identyfikowanie niezałączanych interfejsów sieciowych

Użyj następującego zapytania usługi ARG, aby zidentyfikować interfejsy sieciowe, które nie są dołączone do żadnej maszyny wirtualnej ani prywatnego punktu końcowego.

resources
| where type =~ 'microsoft.network/networkinterfaces'
| where isnull(properties.virtualMachine) and isnull(properties.privateEndpoint)
| project
    ResourceId = tolower(id),
    ResourceName = name,
    PrivateIP = tostring(properties.ipConfigurations[0].properties.privateIPAddress),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Sieciowa grupa zabezpieczeń

Sieciowe grupy zabezpieczeń (NSG) filtrują ruch sieciowy do zasobów platformy Azure i z nich w sieci wirtualnej. Sieciowe grupy zabezpieczeń zawierają reguły zabezpieczeń, które zezwalają na przychodzący i wychodzący ruch sieciowy lub go blokują.

Usuwanie pustych sieciowych grup zabezpieczeń

Zalecenie: Usuń sieciowe grupy zabezpieczeń, które nie są skojarzone z żadnym interfejsem sieciowym ani podsiecią, aby uprościć środowisko i zmniejszyć obciążenie związane z zarządzaniem.

Informacje o pustych sieciowych grupach zabezpieczeń

Grupy zabezpieczeń sieciowych (NSG), które nie są skojarzone z żadnym interfejsem sieciowym ani podsiecią, nie filtrują aktywnie ruchu. Te nieużywane zasoby mogą gromadzić się podczas zmian infrastruktury, dodając bałagan i komplikując inspekcje zabezpieczeń. Usunięcie ich upraszcza zarządzanie siecią i pomaga zachować czyste środowisko.

Note

Centra FinOps mogą automatycznie identyfikować puste sieciowe grupy zabezpieczeń. Dowiedz się więcej.

Identyfikowanie pustych sieciowych grup zabezpieczeń

Użyj następującego zapytania usługi ARG, aby zidentyfikować sieciowe grupy zabezpieczeń, które nie są skojarzone z żadnym interfejsem sieciowym ani podsiecią.

resources
| where type =~ 'microsoft.network/networksecuritygroups'
| where isnull(properties.networkInterfaces) and isnull(properties.subnets)
| project
    ResourceId = tolower(id),
    ResourceName = name,
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Prywatna strefa DNS

Poniższa sekcja zawiera zapytanie ARG dla prywatnego DNS. Ułatwia to uzyskanie wglądu w zasoby prywatnego DNS i upewnienie się, że są one skonfigurowane przy użyciu odpowiednich ustawień.

Zapytanie: Prywatna strefa DNS

To zapytanie usługi ARG analizuje prywatne strefy DNS w środowisku platformy Azure, aby zidentyfikować takie bez linków sieci wirtualnych.

Kategoria

Optymalizacja

Zapytanie

resources
| where type == "microsoft.network/privatednszones"
    and properties.numberOfVirtualNetworkLinks == 0
| project id, PrivateDNSName=name,
    NumberOfRecordSets = tostring(properties.numberOfRecordSets),
    resourceGroup = tostring(strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)),
    vNets = tostring(properties.properties.numberOfVirtualNetworkLinks),
    subscriptionId

Publiczny adres IP

Azure publiczne adresy IP umożliwiają Azure zasobom komunikowanie się z Internetem i innymi publicznymi usługami Azure. Publiczne adresy IP są przypisywane do zasobów, takich jak maszyny wirtualne, moduły równoważenia obciążenia i bramy aplikacji. Statyczne publiczne adresy IP generują koszty, niezależnie od tego, czy są one skojarzone z zasobem.

Powiązane zasoby:

Uaktualnianie podstawowych publicznych adresów IP

Zalecenie: Uaktualnij publiczne adresy IP z wycofanego podstawowego SKU do standardowego SKU, aby zapewnić lepsze bezpieczeństwo i dalszą obsługę.

Informacje o podstawowych publicznych adresach IP

Wariant SKU Basic dla publicznych adresów IP platformy Azure został wycofany 30 września 2025 r. Podstawowe publiczne adresy IP nie mają nadmiarowości strefy, nie obsługują preferencji routingu i są domyślnie otwarte dla ruchu przychodzącego. Uaktualnienie do jednostki SKU w warstwie Standard zapewnia nadmiarowość strefową, domyślnie bezpieczne działanie (zamknięte dla ruchu przychodzącego) oraz obsługę preferencji trasowania.

Note

Centra FinOps mogą automatycznie identyfikować publiczne adresy IP typu Basic. Dowiedz się więcej.

Identyfikowanie podstawowych publicznych adresów IP

Użyj następującego zapytania ARG, aby zidentyfikować publiczne adresy IP w jednostce SKU Basic.

resources
| where type =~ 'microsoft.network/publicipaddresses'
| where sku.name =~ 'Basic'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    AllocationMethod = tostring(properties.publicIPAllocationMethod),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Usuwanie bezczynnych publicznych adresów IP

Zalecenie: Usuń niezałączone statyczne publiczne adresy IP, aby uniknąć niepotrzebnych kosztów sieci.

Informacje o bezczynnych publicznych adresach IP

Statyczne publiczne adresy IP generują koszty niezależnie od tego, czy są skojarzone z zasobem. Nieprzypisane publiczne adresy IP mogą z czasem się gromadzić, gdy zasoby są usuwane, ale powiązane z nimi publiczne adresy IP pozostają. Identyfikacja i usuwanie tych osieroconych zasobów może ograniczyć niepotrzebne koszty.

Note

Centra FinOps mogą automatycznie identyfikować nieprzyłączone publiczne adresy IP. Dowiedz się więcej.

Identyfikowanie bezczynnych publicznych adresów IP

Użyj następującego zapytania ARG, aby zidentyfikować nieprzypisane statyczne publiczne adresy IP, w tym te skojarzone z nieprzypisanymi interfejsami sieciowymi.

resources
| where type =~ 'Microsoft.Network/publicIPAddresses'
    and isempty(properties.ipConfiguration)
    and isempty(properties.natGateway)
    and properties.publicIPAllocationMethod =~ 'Static'
| extend
    PublicIpId = id,
    IPName = name,
    AllocationMethod = tostring(properties.publicIPAllocationMethod),
    SKUName = sku.name,
    Location = location,
    resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| project PublicIpId, IPName, SKUName, resourceGroup, Location, AllocationMethod, subscriptionId
| union (
    Resources
    | where type =~ 'microsoft.network/networkinterfaces'
        and isempty(properties.virtualMachine)
        and isnull(properties.privateEndpoint)
        and isnotempty(properties.ipConfigurations)
    | extend IPconfig = properties.ipConfigurations
    | mv-expand IPconfig
    | extend PublicIpId= tostring(IPconfig.properties.publicIPAddress.id)
    | project PublicIpId
    | join (
        resource
        | where type =~ 'Microsoft.Network/publicIPAddresses'
        | extend
            PublicIpId = id,
            IPName = name,
            AllocationMethod = tostring(properties.publicIPAllocationMethod),
            SKUName = sku.name,
            resourceGroup,
            Location = location
    ) on PublicIpId
    | project
        PublicIpId,
        IPName,
        SKUName,
        resourceGroup,
        Location,
        AllocationMethod,
        subscriptionId
)

Zapytanie: Identyfikowanie metody routingu publicznych adresów IP

To zapytanie usługi ARG analizuje publiczne adresy IP i identyfikuje metodę routingu, metodę alokacji i jednostkę SKU. Analizuje również inne szczegóły publicznych adresów IP skojarzonych z konfiguracją adresu IP.

Kategoria

Optymalizacja

Zapytanie

resources
| where type =~ 'Microsoft.Network/publicIPAddresses'
    and isnotempty(properties.ipConfiguration)
| where tostring(properties.ipTags) == "[]"
| extend
    PublicIpId = id,
    RoutingMethod = id,
    IPName = name,
    AllocationMethod = tostring(properties.publicIPAllocationMethod),
    SKUName = sku.name,
    Location = location,
    resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| project
    PublicIpId,
    IPName,
    RoutingMethod,SKUName,
    resourceGroup,
    Location,
    AllocationMethod,
    subscriptionId

Zapytanie: Sprawdzanie zasad ochrony przed atakami DDoS publicznych adresów IP

Jeśli musisz chronić mniej niż 15 zasobów publicznych adresów IP, warstwa ochrony adresów IP jest bardziej ekonomiczną opcją. Jeśli jednak masz więcej niż 15 zasobów publicznych adresów IP do ochrony, warstwa ochrony sieci stanie się bardziej opłacalna.

Kategoria

Optymalizacja

Zapytanie

resources
| where type == "microsoft.network/publicipaddresses"
| project ddosProtection = tostring(properties.ddosSettings), name
| where ddosProtection has "Enabled"
| count
| project TotalIpsProtected = Count
| extend CheckIpsProtected = iff(TotalIpsProtected >= 15, "Enable Network Protection tier", "Enable PIP DDoS Protection")

Brama sieci wirtualnej

Azure Virtual Network Gateways zapewniają łączność między sieciami wirtualnymi Azure a infrastrukturą lokalną. Bramy generują opłaty godzinowe na podstawie jednostki SKU.

Powiązane zasoby:

Usuń nieużywane bramy sieci VNet

Zalecenie: Usuń bramy sieci wirtualnej, które nie mają żadnych aktywnych połączeń, aby uniknąć niepotrzebnych opłat.

Informacje o nieaktywnych bramach VNet

Bramy sieci wirtualnych wiążą się z kosztami naliczanymi co godzinę w zależności od warstwy SKU, niezależnie od tego, czy są faktycznie używane. Bramy bez żadnych połączeń nie zapewniają łączności obejmującej wiele lokalizacji i reprezentują zmarnowane wydatki. Te bezczynne bramy mogą pozostać po migracji lub zmianie wymagań dotyczących łączności.

Note

Centra FinOps mogą automatycznie identyfikować bezczynne bramy sieci wirtualnej. Dowiedz się więcej.

Identyfikowanie bezczynnych bram sieci wirtualnych

Użyj następującego zapytania usługi ARG, aby zidentyfikować bramy sieci wirtualnej bez żadnych aktywnych połączeń.

resources
| where type == "microsoft.network/virtualnetworkgateways"
| extend resourceGroup = strcat('/subscriptions/', subscriptionId, '/resourceGroups/', resourceGroup)
| project id, GWName=name, resourceGroup, location, subscriptionId
| join kind = leftouter(
    resources
    | where type == "microsoft.network/connections"
    | extend id = tostring(properties.virtualNetworkGateway1.id)
    | project id
) on id
| where isempty(id1)
| project
    id,
    GWName,
    resourceGroup,
    location,
    subscriptionId,
    status=id

Prześlij opinię

Daj nam znać, jak nam idzie, zostawiając krótką opinię. Te recenzje służą do ulepszania i rozszerzania narzędzi i zasobów FinOps.

Prześlij opinię

Jeśli szukasz czegoś konkretnego, zagłosuj na istniejący lub utwórz nowy pomysł. Podziel się pomysłami z innymi osobami, aby uzyskać więcej głosów. Skupiamy się na pomysłach z największą większością głosów.

Głosuj na pomysły lub sugeruj własne


Powiązana zawartość

Powiązane zasoby:

Powiązane rozwiązania:


  • Last updated on