Najlepsze praktyki FinOps w sieci Web

W tym artykule opisano kolekcję sprawdzonych rozwiązań FinOps dotyczących usług internetowych. Udostępnia strategie optymalizacji kosztów, poprawy wydajności i używania zapytań usługi Azure Resource Graph (ARG) w celu uzyskania wglądu w zasoby internetowe. Postępując zgodnie z tymi rozwiązaniami, możesz upewnić się, że usługi internetowe są opłacalne i dostosowane do celów finansowych organizacji.

App Service

W poniższych sekcjach przedstawiono zapytania ARG dla App Service. Te zapytania ułatwiają uzyskanie wglądu w zasoby usługi App Service i upewnienie się, że zostały skonfigurowane przy użyciu odpowiednich ustawień. Analizując plany usługi App Service i wyświetlając zalecenia z usługi Azure Advisor, możesz zoptymalizować zasoby usługi App Service pod kątem wydajności kosztów.

Zapytanie: stan aplikacji internetowej

To zapytanie ARG pobiera stan i podstawowe informacje o aplikacjach internetowych w środowisku platformy Azure.

Kategoria

Monitorowanie

Zapytanie

resources
| where type =~ 'Microsoft.Web/sites'
| project
    id,
    WebAppName = name,
    Type = kind,
    Status = tostring(properties.state),
    WebAppLocation = location,
    AppServicePlan = tostring(properties.serverFarmId),
    WebAppRG = resourceGroup,
    SubscriptionId = subscriptionId
| order by id asc

Usuń puste plany usługi App Service

Zalecenie: Usuń plany usługi App Service, które nie mają hostowanych aplikacji ani funkcji, aby uniknąć niepotrzebnych opłat.

Informacje o pustych planach usługi App Service

Plany usługi App Service definiują zasoby obliczeniowe dla aplikacji internetowych. Płatne plany generują opłaty na podstawie skonfigurowanej jednostki SKU i liczby wystąpień, niezależnie od tego, czy jakiekolwiek aplikacje są na nich hostowane. Puste plany mogą gromadzić się podczas programowania lub gdy aplikacje są przenoszone między planami. Usunięcie nieużywanych planów eliminuje niepotrzebne koszty.

Identyfikowanie pustych planów usługi App Service

Użyj następującego zapytania usługi ARG, aby zidentyfikować plany usługi App Service bez hostowanych aplikacji.

resources
| where type =~ 'microsoft.web/serverfarms'
| where toint(properties.numberOfSites) == 0
| where sku.tier !~ 'Free'
| project
    ResourceId = tolower(id),
    ResourceName = name,
    SKUName = tostring(sku.name),
    SKUTier = tostring(sku.tier),
    Region = location,
    ResourceGroupName = resourceGroup,
    SubscriptionId = subscriptionId

Zapytanie: szczegóły planu usługi App Service

To zapytanie ARG pobiera szczegółowe informacje o planach usługi App Service w Twoim środowisku Azure.

Kategoria

Zarządzanie zasobami

Zapytanie

resources
| where type == "microsoft.web/serverfarms"  and sku.tier !~ 'Free'
| project
    planId = tolower(tostring(id)),
    name,
    skuname = tostring(sku.name),
    skutier = tostring(sku.tier),
    workers = tostring(properties.numberOfWorkers),
    maxworkers = tostring(properties.maximumNumberOfWorkers),
    webRG = resourceGroup,
    Sites = tostring(properties.numberOfSites),
    SubscriptionId = subscriptionId
| join kind=leftouter (
    resources
    | where type == "microsoft.insights/autoscalesettings"
    | project
        planId = tolower(tostring(properties.targetResourceUri)),
        PredictiveAutoscale = properties.predictiveAutoscalePolicy.scaleMode,
        AutoScaleProfiles = properties.profiles,
        resourceGroup
) on planId

Prześlij opinię

Daj nam znać, jak nam idzie, zostawiając krótką opinię. Te recenzje służą do ulepszania i rozszerzania narzędzi i zasobów FinOps.

Jeśli szukasz czegoś konkretnego, zagłosuj na istniejący lub utwórz nowy pomysł. Podziel się pomysłami z innymi osobami, aby uzyskać więcej głosów. Skupiamy się na pomysłach z największą większością głosów.

Powiązana zawartość

Powiązane zasoby:

• Struktura FinOps

Powiązane rozwiązania:

• Raporty usługi Power BI dla zestawu narzędzi FinOps
• Węzły FinOps
• Skoroszyty FinOps
• Aparat optymalizacji