Jak utworzyć dokument z przestrzeniami nazw w Visual Basic (LINQ to XML)

W tym artykule pokazano, jak utworzyć dokument z przestrzeniami nazw w Visual Basic.

W przypadku używania literałów XML w Visual Basic użytkownicy mogą definiować jedną globalną domyślną przestrzeń nazw XML. Ta przestrzeń nazw jest domyślną przestrzenią nazw dla literałów XML i właściwości XML. Domyślną przestrzeń nazw XML można zdefiniować na poziomie projektu lub pliku. Jeśli jest ona zdefiniowana na poziomie pliku, zastępuje domyślną przestrzeń nazw na poziomie projektu.

Można również zdefiniować inne przestrzenie nazw i określić prefiksy przestrzeni nazw dla tych przestrzeni nazw. Słowo kluczowe służy Imports do definiowania obu typów przestrzeni nazw.

Aby uzyskać więcej informacji, zobacz Literały XML w Visual Basic.

Należy pamiętać, że domyślna przestrzeń nazw XML dotyczy tylko elementów, a nie atrybutów. Atrybuty są domyślnie w domyślnej przestrzeni nazw. Można jednak użyć prefiksu przestrzeni nazw, aby umieścić atrybut w przestrzeni nazw.

Przykład: tworzenie dokumentu, który ma przestrzeń nazw

W tym przykładzie tworzony jest dokument zawierający przestrzeń nazw.

Imports <xmlns:aw="http://www.adventure-works.com">
Module Module1
    Sub Main()
        Dim root As XElement = _
            <aw:Root>
                <aw:Child aw:Att="attvalue"/>
            </aw:Root>
        Console.WriteLine(root)
    End Sub
End Module

Ten przykład generuje następujące wyniki:

<aw:Root xmlns:aw="http://www.adventure-works.com">
  <aw:Child aw:Att="attvalue" />
</aw:Root>

Przykład: utwórz dokument, który ma dwie przestrzenie nazw, jeden z prefiksem

W tym przykładzie tworzony jest dokument zawierający dwie przestrzenie nazw. Jedną z nich jest domyślna przestrzeń nazw, a druga ma prefiks.

Imports <xmlns="http://www.adventure-works.com">
Imports <xmlns:fc="www.fourthcoffee.com">

Module Module1

    Sub Main()
        Dim root As XElement = _
            <Root>
                <Child Att="attvalue"/>
                <fc:Child2>child2 content</fc:Child2>
            </Root>
        Console.WriteLine(root)
    End Sub

End Module

Ten przykład generuje następujące wyniki:

<Root xmlns:fc="www.fourthcoffee.com" xmlns="http://www.adventure-works.com">
  <Child Att="attvalue" />
  <fc:Child2>child2 content</fc:Child2>
</Root>

Przykład: tworzenie dokumentu, który ma dwie przestrzenie nazw, oba z prefiksami

Poniższy przykład tworzy dokument zawierający dwie przestrzenie nazw, z których oba mają prefiksy przestrzeni nazw.

Podczas serializacji drzewa XML LINQ to XML emituje deklaracje przestrzeni nazw zgodnie z wymaganiami, tak aby każdy element znajduje się w wyznaczonej przestrzeni nazw.

Imports <xmlns:aw="http://www.adventure-works.com">
Imports <xmlns:fc="www.fourthcoffee.com">

Module Module1

    Sub Main()
        Dim root As XElement = _
            <aw:Root>
                <fc:Child>
                    <aw:DifferentChild>other content</aw:DifferentChild>
                </fc:Child>
                <aw:Child2>c2 content</aw:Child2>
                <fc:Child3>c3 content</fc:Child3>
            </aw:Root>
        Console.WriteLine(root)
    End Sub

End Module

Ten przykład generuje następujące wyniki:

<aw:Root xmlns:fc="www.fourthcoffee.com" xmlns:aw="http://www.adventure-works.com">
  <fc:Child>
    <aw:DifferentChild>other content</aw:DifferentChild>
  </fc:Child>
  <aw:Child2>c2 content</aw:Child2>
  <fc:Child3>c3 content</fc:Child3>
</aw:Root>

Zobacz też

  • Last updated on